# 01 -> changing directories:
  setopt autocd
  setopt autopushd
unsetopt cdablevars
unsetopt chasedots
  setopt chaselinks
  setopt pushdignoredups
unsetopt pushdminus
unsetopt pushdsilent
unsetopt pushdtohome
# 02 -> completion:
  setopt alwayslastprompt
  setopt alwaystoend
  setopt autolist
  setopt automenu
  setopt autonamedirs
  setopt autoparamkeys
  setopt autoparamslash
  setopt autoremoveslash
unsetopt bashautolist
  setopt completealiases
  setopt completeinword
unsetopt globcomplete
  setopt hashlistall
  setopt listambiguous
unsetopt listbeep
  setopt listpacked
unsetopt listrowsfirst
  setopt listtypes
unsetopt menucomplete
unsetopt recexact
# 03 -> expansion and globbing:
  setopt badpattern
  setopt bareglobqual
unsetopt braceccl
  setopt caseglob
  setopt casematch
unsetopt cshnullglob
  setopt equals
  setopt extendedglob
  setopt glob
unsetopt globassign
  setopt globdots
unsetopt globsubst
unsetopt histsubstpattern
unsetopt ignorebraces
unsetopt kshglob
unsetopt magicequalsubst
  setopt markdirs
  setopt multibyte
  setopt nomatch
unsetopt nullglob
  setopt numericglobsort
unsetopt rcexpandparam
unsetopt rematchpcre
unsetopt shglob
  setopt warncreateglobal
# 04 -> history:
  setopt appendhistory
  setopt banghist
unsetopt extendedhistory
unsetopt histallowclobber
unsetopt histbeep
  setopt histexpiredupsfirst
unsetopt histfcntllock
  setopt histfindnodups
unsetopt histignorealldups
  setopt histignoredups
  setopt histignorespace
  setopt histnofunctions
  setopt histnostore
  setopt histreduceblanks
unsetopt histsavebycopy
unsetopt histsavenodups
  setopt histverify
  setopt incappendhistory
unsetopt sharehistory
# 05 -> initilisation:
unsetopt allexport
unsetopt globalexport
unsetopt globalrcs
  setopt rcs
# 06 -> input/output:
  setopt aliases
unsetopt clobber
  setopt correct
unsetopt correctall
  setopt dvorak
  setopt flowcontrol
unsetopt ignoreeof
unsetopt interactivecomments
  setopt hashcmds
  setopt hashdirs
unsetopt mailwarning
unsetopt pathdirs
unsetopt printeightbit
unsetopt printexitvalue
unsetopt rcquotes
unsetopt rmstarsilent
unsetopt rmstarwait
  setopt shortloops
unsetopt sunkeyboardhack
# 07 -> job control:
  setopt autocontinue
unsetopt autoresume
  setopt bgnice
  setopt checkjobs
  setopt hup
  setopt longlistjobs
  setopt monitor
  setopt notify
# 08 -> prompting:
  setopt promptbang
  setopt promptcr
  setopt promptsp
  setopt promptpercent
  setopt promptsubst
unsetopt transientrprompt
# 09 -> scripts and functions:
unsetopt cbases
unsetopt cprecedences
  setopt debugbeforecmd
unsetopt errexit
unsetopt errreturn
  setopt evallineno
  setopt exec
  setopt functionargzero
unsetopt localoptions
unsetopt localtraps
  setopt multifuncdef
  setopt multios
unsetopt octalzeroes
unsetopt typesetsilent
unsetopt verbose
unsetopt xtrace
# 10 -> shell emulation:
unsetopt bashrematch
  setopt bsdecho
unsetopt cshjunkiehistory
  setopt cshjunkieloops
unsetopt cshjunkiequotes
unsetopt cshnullcmd
unsetopt ksharrays
unsetopt kshautoload
  setopt kshoptionprint
unsetopt kshtypeset
unsetopt kshzerosubscript
unsetopt posixaliases
unsetopt posixbuiltins
unsetopt posixidentifiers
unsetopt shfileexpansion
unsetopt shnullcmd
unsetopt shoptionletters
unsetopt shwordsplit
unsetopt trapsasync
# 11 -> shell state:
#  setopt interactive # do not set!
#  setopt login       # do not set!
#unsetopt privileged  # do not set!
#unsetopt restricted  # do not set!
#  setopt shinstdin   # do not set!
unsetopt singlecommand
# 12 -> zle:
unsetopt beep
unsetopt combiningchars
unsetopt emacs
unsetopt overstrike
unsetopt singlelinezle
  setopt vi
  setopt zle

# global environment exports:
export HTTP_PROXY=http://127.0.0.1:8118
export H="/howl"
export XDG_CACHE_HOME="${HOME:-/howl/conf}/cache"
export XDG_CONFIG_HOME="${HOME:-/howl/conf}"
export XDG_CONFIG_DIR="${XDG_CONFIG_HOME}"
export XDG_CONFIG_DIRS="/etc/xdg:${XDG_CONFIG_HOME}"
export XDG_DATA_HOME="${XDG_CONFIG_HOME}/share"
export XDG_DESKTOP_DIR="/tmp/.${UID}"
export XDG_DOCUMENTS_DIR="${H}/rite"
export XDG_DOWNLOAD_DIR="${H}/down"
export XDG_MUSIC_DIR="${H}/muzk"
export XDG_PICTURES_DIR="${H}/foto"
export XDG_PUBLICSHARE_DIR="/tmp/.${UID}"
export XDG_TEMPLATES_DIR="/tmp/.${UID}"
export XDG_VIDEOS_DIR="${H}/vide"
export XAUTHORITY="${XDG_CONFIG_HOME}/xorg/.Xauthority"
export HISTFILE="${ZDOTDIR:-${XDG_CONFIG_HOME}/zsh}/.history"
export HISTSIZE=1400
export SAVEHIST=1000
export DIRSTACKSIZE=20
export PAGER="/usr/bin/most"
export SDCV_PAGER="/bin/more"
export SDCV_HISTSIZE=0
export EDITOR="/usr/bin/vim"
#export MOST_SWITCHES="-c"
export MOST_EDITOR="${EDITOR}"
export FCEDIT="${EDITOR}"
export BZR_EDITOR="${EDITOR}"
export BZR_HOME="${XDG_CONFIG_HOME}/bazaar"
export BROWSER="/usr/bin/w3m"
export HOMEPAGE="https://bbs.archlinux.org/search.php?action=show_new"
export SHELL="/bin/zsh"
export GPG_TTY="$(tty)"
export LANG="en_US.UTF-8"
export LC_ALL="en_US.UTF-8"
export LC="en_US.UTF-8"
export LESSCHARSET="UTF-8"
export LESSHISTFILE="${XDG_PUBLICSHARE_DIR}/.${UID}/less_history"
export LESS_TERMCAP_mb=$'\E[01;31m'
export LESS_TERMCAP_md=$'\E[00;35m'
export LESS_TERMCAP_me=$'\E[0m'
export LESS_TERMCAP_se=$'\E[0m'
export LESS_TERMCAP_so=$'\E[00;47;30m'
export LESS_TERMCAP_ue=$'\E[0m'
export LESS_TERMCAP_us=$'\E[00;34m'

# file management:
alias ls="/bin/ls -h --file-type --time-style='+%y-%m-%d %H%M%S' --color=auto --group-directories-first"
alias la="ls -A"
alias lb="ls -Ssr"
alias lt="ls -tr"
alias lm="lt -c"
alias lx="ls -X"
alias lls="ls -l"
alias lla="lls -A"
alias llb="lls -Ssr"
alias llt="lls -tr"
alias llm="llt -c"
alias llx="lx -l"
alias rd="/bin/rm -r"

# useless quick views/edits:
alias wika="${BROWSER:-/usr/bin/w3m} /usr/share/doc/arch-wiki/html/index.html"
alias sedit="${EDITOR:-/usr/bin/vim} -p ${HOME}/.stumpwmrc ${XDG_CONFIG_DIR:-${HOME}}/stumpwm/{functions,macros,commands,hooks,key-maps}.lisp"
alias zedit="${EDITOR:-/usr/bin/vim} -p ${HOME}/{.zshrc,zsh/{functions,aliases,exports,options,.zlogin}}"
alias xedit="${EDITOR:-/usr/bin/vim} -p ${XDG_CONFIG_DIR:-${HOME}}/xorg/{xinitrc,Xdefaults}"
alias zload=". ${HOME}/.zshrc"
alias xload="xrdb -load ${XDG_CONFIG_DIR:-${HOME}}/xorg/Xdefaults &>/dev/null"
alias gh="cd ${H:-/howl}"

# program masquing:
alias sudo='/usr/bin/sudo '
alias svim="sudo ${EDITOR:-/usr/bin/vim}"
alias info="/usr/bin/info --vi-keys"
alias diff="/usr/bin/colordiff"
alias grep="/bin/grep --color=auto"
alias mutt="/usr/bin/mutt -F ${XDG_CONFIG_DIR:-${HOME}}/mutt/muttrc"
alias xskat="/usr/bin/xskat -opt ${XDG_CONFIG_DIR:-${HOME}}/xorg/xskat.opt -list ${XDG_CONFIG_DIR:-${HOME}}/xorg/xskat.lst"
alias offlineimap="/usr/bin/offlineimap -c ${XDG_CONFIG_DIR:-${HOME}}/.offlineimap/offlineimaprc"
alias rtorrent="/usr/bin/rtorrent -o http_capath=/etc/ssl/certs"
alias startx="cd ~/ && /usr/bin/startx ${XDG_CONFIG_DIR:-${HOME}}/xorg/xinitrc -- -nolisten tcp -once -retro ; pushd -q +1"

# system/media shortcuts:
alias psu="print 'ELAPSETIME  %CPU NI +?   LWPID # COMMAND';/bin/ps -U root,privoxy,15,http,daemon,nobody,unbound --deselect -C tmux,urxvt -H hoetime:10,%cpu:5,ni:2,stat:4,pid:5,rtprio:1,args"
alias psr="print 'ELAPSETIME  %CPU NI +?   LWPID # COMMAND';/bin/ps -u root -U root -H hoetime:10,%cpu:5,ni:2,stat:4,pid:5,rtprio:1,args"
alias psa="print 'ELAPSETIME USER  %CPU NI +?   LWPID # COMMAND';/bin/ps -H haxoetime:10,user:4,%cpu:5,ni:2,stat:4,pid:5,rtprio:1,args"
alias pso="print 'ELAPSETIME USER  %CPU NI +?   LWPID # COMMAND';/bin/ps -U root,h --deselect -u root,h -H hoetime:10,user:4,%cpu:5,ni:2,stat:4,pid:5,rtprio:1,args"
alias dfu="/bin/df -hTP -x debugfs"
alias dii="/usr/bin/di -x debugfs -d h -Af sMTbuf"
alias mii="/usr/bin/mi -x debugfs"
alias loadavg='print ${$(</proc/loadavg)[1,3]}'
alias daemons='lt /run/daemons'
alias reboot='/bin/sync && sudo /sbin/reboot'
alias {poweroff,pow}='/bin/sync && sudo /sbin/poweroff'
alias mix2="/usr/local/bin/ossvol --speakers --quiet && /usr/local/bin/ossvol -a"
alias mix3="/usr/local/bin/ossvol --headphones --quiet && /usr/local/bin/ossvol -a"
alias siteget="/usr/bin/wget --recursive --page-requisites --convert-links --html-extension --no-parent --random-wait --limit-rate=20K -U Mozilla -l" #depth, then url

# database/package management:
alias upf="sudo /usr/bin/fc-cache -vr"
alias upd="sudo /etc/cron.daily/updatedb"
alias upm="sudo /usr/bin/mandb --quiet"
alias pacman="sudo /usr/bin/pacman-color"

# use history, but skip certain cmds/args from being written:
function zshaddhistory {
  local line cmd
  line=${1%%$'\n'} ; cmd=${line%% *}
  [[ ${#line} -ge 5
      && ${cmd} != (history|fc|mpq|srm|rms|rds)
      && ${cmd} != ([szx]edit|[zx]load|zhist|wika)
  ]] && (( ! $argv[(I)*unrl*|*spar*|*losetup*|*aespipe*|*litika*|sudo rm*] ))
}

## test arguments and [if valid] prepend file:// to local requests:
#function {jumanji,vimprobable} {
#  setopt no_warncreateglobal
#  for i in {1..999}; do # this will break when arguments run out
#    if [[ ${+i} == 1 && ${(P)i} != ${(P)$(($i - 1))} ]]; then
#      if [[ -f $PWD/${(P)i} ]]; then __urls=(${__urls} file://$PWD/${(P)i})
#      elif [[ -f ${(P)i} ]]; then __urls=(${__urls} file://${(P)i})
#      else __urls=(${__urls} ${(P)i}) ; fi
#    else if [[ ${+__urls} == 1 ]]; then
#        command $0 ${__urls} 2>/dev/null ; unset __urls ; break ; fi ; fi
#  done
#}

# attach rtorrent from daemon mode to view/edit torrents:
function rot {
  if [[ ${TERM} =~ screen ]]; then
    print "Aborting, please avoid nesting sessions.."
  else
    /usr/bin/tmux -S /tmp/.${UID}/tmux/rtorrent attach-session
  fi
}

# check ownership of given argument, as determined by pacman:
function owns {
  if [[ -n $(for each in ${PATH//:\\\n}; do
             find ${each}/$1 2>/dev/null ; done) ]]
  then pacman -Qo $(which -p $1)
  else pacman -Qo $1 ; fi
}

# jump to previous directory by integer or reg-exp, also list dirs,
# else jump to last visited directory if no argument supplied:
function back {
  if [[ $# == 1 ]]; then
    case $1 {
      <->)  pushd -q +$1 2>/dev/null ;;
      --)   dirs -lpv|sed '2s|$| \[last\]|' ;;
      *)    [[ -n $(dirs -lpv|grep -i $1|grep -v ${PWD}) ]] && \
              pushd -q +${$(dirs -lpv|grep -i $1|grep -v ${PWD})[1]}
    }
  else pushd -q - 2>/dev/null ; fi
}

# go up Nth amount of directories:
function up {
  local arg=${1:-1};
  while [ ${arg} -gt 0 ]; do
    cd .. >&/dev/null;
    arg=$((${arg} - 1));
  done
}

# copy and follow file to new dir:
function cpf {
  if [[ -d $*[-1] ]]; then
    cp $* && cd $*[-1]
  elif [[ -d ${*[-1]%/*} ]]; then
    cp $* && cd ${*[-1]%/*}
  fi
}

# move and follow file to new dir:
function mvf {
  if [[ -d $*[-1] ]]; then
    mv $* && cd $*[-1]
  elif [[ -d ${*[-1]%/*} ]]; then
    mv $* && cd ${*[-1]%/*}
  fi
}

# show ps information with simple output for scripts, quick views, etc:
function psi {
  if [[ ${#${@:/$0}} -ge 2 ]]; then
    case $1 {
      '-C'|'-c')  ps -C $2 hopid,args ;; # by- command name
      '-G'|'-g')  ps -G $2 hopid,args ;; # by- real group id (RGID)/name
      '-U'|'-u')  ps -U $2 hopid,args ;; # by- effective user ID (EUID)/name
      '-P'|'-p')  ps -p $2 hoargs ;;     # by- pid
      '-S'|'-s')  ps -s $2 hopid,args ;; # by- session id
      '-T'|'-t')  ps -t $2 hopid,args ;; # by- tty
      *) print "invalid selection. read: man ps (section: process selection by list)"
    }
  else
        << EOP
(show process information by .. )
psi -c ARG  | command name
psi -g ARG  | group id
psi -u ARG  | user id
psi -p ARG  | pid
psi -s ARG  | session id
psi -t ARG  | tty
EOP
  fi
}

# native function for showing 256 colors, properly formatted:
function 256co {
  for line in {0..15}; do for col in {0..15}; do
      local code=$(( $col * 16 + ${line} ))
      printf $'\e[38;05;%dm %03d' ${code} ${code}
    done
  print ; done
}

# function to quickly play video files:
function mpq {
  setopt no_warncreateglobal
  [[ -z ${DISPLAY} && $(tty) = /dev/tty[1-3] ]] && _mopt=(-vo fbdev)
  case $1 {
    'm') local _vol=${$(command ossmix|grep outvol)[-2]}
         command ossmix vmix0-outvol 25 &>/dev/null
         command mplayer ${_mopt} -volume 100 -fs -really-quiet -msglevel all=0 ${@:/$1} &>/dev/null
         command ossmix vmix0-outvol ${_vol} &>/dev/null ;;
    *)   command mplayer ${_mopt} -volume 100 -really-quiet -msglevel all=0 ${@} &>/dev/null
  }
  setopt warncreateglobal
}

# function to quickly view word definitions:
function sd {
  case $1 in
    '-r'|'-ru') sdcv -u "en-ru-bars" ${@:/$1} 2>/dev/null ;;
    '-w'|'-wordnet') sdcv -u "WordNet" ${@:/$1} 2>/dev/null ;;
    '-t'|'-thesaurus') sdcv -u "English Thesaurus" ${@:/$1} 2>/dev/null ;;
    '-a'|'-all') sdcv ${@:/$1} 2>/dev/null ;;
    *) sdcv $@ 2>/dev/null
  esac
}

# un-smart function for my todo lists:
function todo {
  case $# {
    0) command ls -1 ${H:-/howl}/othe/.TODO_* ;;
    1) command vim ${H:-/howl}/othe/.TODO_$1 ;;
    *) command vim ${H:-/howl}/othe/.TODO_${@// /_}
  }
}

# un-smart function for viewing/editing history file (still use 'fc/history'):
function zhist {
  if [[ $# == 1 ]]; then
    case $1 {
      e)  ${EDITOR:-/usr/bin/vim} ${ZDOTDIR:-${HOME}/zsh}/.history ;;
      a)  <${ZDOTDIR:-${HOME}/zsh}/.history | less ;;
      *)  <${ZDOTDIR:-${HOME}/zsh}/.history|grep -i $1
    }
  fi
}

# quirky tmux function:
function tmux {
  if [[ ${@[-2]} == '--' ]]; then
    command tmux ${@%--}
  else
    case ${+DISPLAY} in
      0)  command tmux -S /tmp/.${UID}/tmux/default $@ ;;
      1)  command tmux -S /tmp/.${UID}/tmux/xorg $@ ;;
    esac
  fi
}

# one-liners/micro functions:
function flashproc { for f (${$(file /proc/$(pidof luakit)/fd/*|gawk '/\/tmp\/Flash/ {print $1}')//:}){print - "$f"} }
function lss { ls -- ${1:-.}/*(D.om) }
function rc { [[ -n $1 ]] && sudo /etc/rc.d/$1 ${@:/$1} }
function alv { <${${$(command find ${H:-/howl}/othe/archive/installed_*)}[${1:--1}]}|w3m -o pagerline=1000 -o confirm_qq=0 }
function mkcd { command mkdir -p "$@" && cd "$@" }
function pubip { curl -m 30 http://automation.whatismyip.com/n09230945.asp }
function newmail { print - ${(Fw)#$(find /howl/mail/*/*/new -type f)} }
function qdep { pacman-color -Q $@ $(pacman-color -Qi $@|grep Depends|cut -d: -f2-|sed -E 's|>\S+\>||g') }
function timec { print "$(date +'%T %Y-%m-%d')" ; while sleep 1 ; do printf '\r%s ' "$(date +'%T %Y-%m-%d')" ; done }
function dropcache { sync && command su -s /bin/zsh -c 'echo 1 > /proc/sys/vm/drop_caches && echo 2 > /proc/sys/vm/drop_caches' root }